A contra-rotor is a geared mechanism that drives two coaxial propellers in opposite directions, magnifying thrust while cancelling angular momentum.

// Contra-Rotor Assembly
// A contra-rotor is a geared mechanism that drives two coaxial propellers in opposite directions, magnifying thrust while cancelling angular momentum.
// Categories: Aerospace

// Define units
@settings(defaultLengthUnit = mm)

// Import Subassemblies
import "contra.kcl" as contra
import "primary.kcl" as primary
import "secondary.kcl" as secondary
import "tertiary.kcl" as tertiary


// Contra-Rotor Module
// Shaft, spine teeth, and sample instances
// Categories: Aerospace

@settings(defaultLengthUnit = mm)

// Import gear and propeller
import * from "helical.kcl"
import * from "propeller.kcl"

// Revolve the contra-shaft
shaft = startSketchOn(YZ)
  |> startProfile(at = [-100, 100])
  |> yLine(endAbsolute = 150)
  |> xLine(length = -200)
  |> yLine(endAbsolute = 80)
  |> xLine(length = -250)
  |> yLine(endAbsolute = 30, tag = $seg01)
  |> xLine(length = 370)
  |> yLine(length = 20)
  |> tangentialArc(angle = -45deg, radius = 10, tag = $seg02)
  |> angledLine(angle = tangentToEnd(seg02), length = 60)
  |> yLine(endAbsolute = profileStartY())
  |> xLine(endAbsolute = profileStartX())
  |> close()
  |> revolve(axis = X)

// Spline shaft inputs
toothWidth = 10
toothHeight = 6
shaftDiameter = 148

// Tooth angle and count
toothAngleDeg = (toothWidth / shaftDiameter * 360 / PI): deg
toothCount = round(180deg / toothAngleDeg)

// Sketch the spline portion of the shaft
spine = startSketchOn(shaft, face = seg01)
  |> startProfile(at = [shaftDiameter / 2, 0])
  |> arc(angleStart = 0deg, angleEnd = toothAngleDeg, diameter = shaftDiameter)
  |> angledLine(angle = toothAngleDeg, length = toothHeight)
  |> arc(angleStart = toothAngleDeg, angleEnd = 2 * toothAngleDeg, diameter = shaftDiameter + 2 * toothHeight)
  |> angledLine(angle = 2 * toothAngleDeg, length = -toothHeight)
  |> line(endAbsolute = polar(angle = 360deg / toothCount, length = shaftDiameter / 2))
  |> patternCircular2d(instances = toothCount, center = [0, 0])
  |> close()
  |> extrude(length = 200)

// Hollow the front of the shaft
frontBore = startSketchOn(spine, face = END)
  |> circle(center = [0, 0], radius = 40)
  |> extrude(length = -100)

// Create a rear step and bore
rearStep = startSketchOn(spine, face = END)
  |> circle(diameter = 100)
  |> extrude(length = 20)
rearBore = startSketchOn(rearStep, face = END)
  |> circle(center = [0, 0], radius = 37.48)
  |> extrude(length = -20)

// Build helical gear and propeller bodies
helicalGear(nTeeth = 28, helixAngle = -25deg, bore = 300)
  |> translate(y = -200)

propeller(
       twistAngle = -75deg,
       toothWidth = toothWidth,
       toothHeight = toothHeight,
       shaftDiameter = shaftDiameter,
     )
  |> translate(y = -630)


// Helical Gear Utility
// Generates an involute helical gear solid
// Categories: Mechanical

// Declare units
@settings(defaultLengthUnit = mm)

// Gear generator
export fn helicalGear(nTeeth, helixAngle, bore) {
  // Gear parameters
  gearModule = 16.0
  pressureAngle = 20deg
  gearHeight = 100
  pitchDiameter = gearModule * nTeeth
  addendum = gearModule
  dedendum = 1.25 * gearModule
  baseDiameter = pitchDiameter * cos(pressureAngle)
  tipDiameter = pitchDiameter + 2 * gearModule

  // Gear solid
  gear = startSketchOn(XZ)
    |> startProfile(at = polar(angle = 0, length = baseDiameter / 2))
    |> involuteCircular(
         startDiameter = baseDiameter,
         endDiameter = tipDiameter,
         angle = 0,
         tag = $seg01,
       )
    |> line(endAbsolute = polar(angle = 160deg / nTeeth, length = tipDiameter / 2))
    |> involuteCircular(
         startDiameter = baseDiameter,
         endDiameter = tipDiameter,
         angle = -(4 * atan(segEndY(seg01) / segEndX(seg01))),
         reverse = true,
       )
    |> line(endAbsolute = polar(angle = 360deg / nTeeth, length = baseDiameter / 2))
    |> patternCircular2d(
         instances = nTeeth,
         center = [0, 0],
         arcDegrees = 360deg,
         rotateDuplicates = true,
       )
    |> close()
    |> subtract2d(tool = circle(diameter = bore))
    |> extrude(length = gearHeight, twistAngle = (360 * gearHeight * tan(helixAngle) / (PI * pitchDiameter)): deg, twistAngleStep = 0)

  return gear
}


// Primary Shaft Module
// Main shaft, spine teeth, and demo instances
// Categories: Aerospace

@settings(defaultLengthUnit = mm)

// Import gear and propeller
import * from "helical.kcl"
import * from "propeller.kcl"

// Revolve the primary shaft
primaryShaft = startSketchOn(YZ)
  |> startProfile(at = [0, 0])
  |> xLine(length = 100)
  |> yLine(length = -30)
  |> angledLine(angle = 45deg, length = -10)
  |> xLine(endAbsolute = 0)
  |> yLine(endAbsolute = -85)
  |> xLine(length = -100, tag = $seg01)
  |> yLine(endAbsolute = -65)
  |> xLine(endAbsolute = -800)
  |> yLine(endAbsolute = -60)
  |> xLine(endAbsolute = -850)
  |> yLine(endAbsolute = profileStartY(), tag = $seg02)
  |> xLine(endAbsolute = profileStartX())
  |> close()
  |> revolve(axis = X)

// Spline shaft inputs
toothWidth = 10
toothHeight = 6
shaftDiameter = 105

// Tooth angle and count
toothAngleDeg = (toothWidth / shaftDiameter * 360 / PI): deg
toothCount = round(180deg / toothAngleDeg)

// Sketch the spline portion of the shaft
primarySpine = startSketchOn(primaryShaft, face = seg02)
  |> startProfile(at = [shaftDiameter / 2, 0])
  |> arc(angleStart = 0deg, angleEnd = toothAngleDeg, diameter = shaftDiameter)
  |> angledLine(angle = toothAngleDeg, length = toothHeight)
  |> arc(angleStart = toothAngleDeg, angleEnd = 2 * toothAngleDeg, diameter = shaftDiameter + 2 * toothHeight)
  |> angledLine(angle = 2 * toothAngleDeg, length = -toothHeight)
  |> line(endAbsolute = polar(angle = 360deg / toothCount, length = shaftDiameter / 2))
  |> patternCircular2d(instances = toothCount, center = [0, 0])
  |> close()
  |> extrude(length = 200)

// Extend the front of the shaft
frontExtension = startSketchOn(primarySpine, face = END)
  |> circle(center = [0, 0], radius = 30)
  |> extrude(length = 50)

// Build the gear and propeller bodies
helicalGear(nTeeth = 32, helixAngle = 25deg, bore = 170)

propeller(
       twistAngle = 75deg,
       toothWidth = toothWidth,
       toothHeight = toothHeight,
       shaftDiameter = shaftDiameter,
     )
  |> translate(y = -950)

// Model the nose cone
noseCone = startSketchOn(YZ)
  |> startProfile(at = [-1100, 0])
  |> yLine(length = -30)
  |> line(end = [50, -28])
  |> xLine(length = 20)
  |> yLine(length = -25)
  |> tangentialArc(angle = -90deg, radius = 15)
  |> tangentialArc(endAbsolute = [-1280, 0])
  |> line(endAbsolute = [profileStartX(), profileStartY()])
  |> close()
  |> revolve(axis = X)
  |> appearance(color = "#e88811", metalness = 10, roughness = 80)


// Propeller Generator
// Rotating blade set with hub and twisted blades
// Categories: Aerospace

@settings(defaultLengthUnit = mm)

// Propeller function
export fn propeller(twistAngle, toothWidth, toothHeight, shaftDiameter) {
  // Hub parameters
  bladeCount = 5
  bladeDiameter = 2500
  hubDiameter = 200
  hubThickness = 150

  // Spline shaft mounting parameters
  toothAngleDeg = (toothWidth / shaftDiameter * 360 / PI): deg
  toothCount = round(180deg / toothAngleDeg)

  // Sketch the spline mounting interface
  toothSketch = startSketchOn(XZ)
    |> startProfile(at = [shaftDiameter / 2, 0])
    |> arc(angleStart = 0deg, angleEnd = toothAngleDeg, diameter = shaftDiameter)
    |> angledLine(angle = toothAngleDeg, length = toothHeight)
    |> arc(angleStart = toothAngleDeg, angleEnd = 2 * toothAngleDeg, diameter = shaftDiameter + 2 * toothHeight)
    |> angledLine(angle = 2 * toothAngleDeg, length = -toothHeight)
    |> line(endAbsolute = polar(angle = 360deg / toothCount, length = shaftDiameter / 2))
    |> patternCircular2d(instances = toothCount, center = [0, 0])
    |> close()

  // Create a central hub with a spline interior
  hub = startSketchOn(XZ)
    |> circle(diameter = hubDiameter, tag = $seg01)
    |> subtract2d(tool = toothSketch)
    |> extrude(
         length = hubThickness,
         symmetric = true,
         tagEnd = $capEnd001,
         tagStart = $capStart001,
       )
    |> fillet(
         tags = [
           getCommonEdge(faces = [seg01, capEnd001]),
           getCommonEdge(faces = [seg01, capStart001])
         ],
         radius = hubThickness / 10,
       )

  // Blade design space
  bladeRevolve = startSketchOn(XZ)
    |> startProfile(at = polar(angle = 40deg, length = hubDiameter / 2.01))
    |> arc(angleStart = 200, angleEnd = 290, radius = bladeDiameter / 50)
    |> tangentialArc(end = [
         bladeDiameter / 2.6,
         bladeDiameter / 30
       ])
    |> tangentialArc(endAbsolute = [bladeDiameter / 2, 0.01])
    |> yLine(endAbsolute = 0)
    |> xLine(endAbsolute = profileStartX())
    |> yLine(endAbsolute = profileStartY())
    |> close()
    |> revolve(axis = X)
    |> subtract(tools =     startSketchOn(XY)
      |> circle(diameter = hubDiameter)
      |> extrude(length = hubThickness * 5, symmetric = true))

  // Blade section and twist
  bladeTwist = startSketchOn(YZ)
    |> startProfile(at = [bladeDiameter / 10, 0])
    |> arc(angleStart = 0, angleEnd = 83, radius = 0.05)
    |> tangentialArc(endAbsolute = [-lastSegX(), lastSegY()])
    |> tangentialArc(angle = 83deg, radius = 0.05)
    |> mirror2d(axis = X)
    |> close()
    |> extrude(length = bladeDiameter / 1.9, twistAngle = twistAngle)

  // Blades pattern
  blades = intersect([bladeRevolve, bladeTwist])
    |> patternCircular3d(instances = bladeCount, axis = Y, center = [0, 0, 0])

  // Return assembly
  return [hub, blades]
    |> appearance(color = "#e88811", metalness = 10, roughness = 80)
}


// Secondary Shaft Module
// Offset shaft with gear placements
// Categories: Aerospace

@settings(defaultLengthUnit = mm)

// Import gear and propeller
import * from "helical.kcl"
import * from "propeller.kcl"

// Revolve the secondary shaft
secondaryShaft = startSketchOn(offsetPlane(YZ, offset = 392))
  |> startProfile(at = [0, 0])
  |> xLine(length = 426.83)
  |> yLine(length = -40)
  |> angledLine(angle = 45deg, length = -10)
  |> xLine(endAbsolute = 50)
  |> yLine(endAbsolute = profileStartY() - 80)
  |> xLine(length = -400)
  |> yLine(length = 30)
  |> xLine(length = -80)
  |> angledLine(angle = -45deg, length = -6)
  |> yLine(endAbsolute = profileStartY())
  |> xLine(endAbsolute = profileStartX())
  |> close()
  |> revolve(axis = {
       direction = [1, 0],
       origin = [392, 0]
     })

// Build and position the gears for the secondary shaft
helicalGear(nTeeth = 16, helixAngle = -25deg, bore = 160)
  |> translate(x = 392)
  |> rotate(pitch = 3)

helicalGear(nTeeth = 14, helixAngle = -25deg, bore = 160)
  |> translate(y = -200, x = 392)


// Tertiary Shaft Module
// Short offset shaft with small gear
// Categories: Aerospace

@settings(defaultLengthUnit = mm)

// Import gear and propeller
import * from "helical.kcl"
import * from "propeller.kcl"

// Model the side shaft
tertiaryShaft = startSketchOn(offsetPlane(YZ, offset = 279))
  |> startProfile(at = [-100, -211])
  |> yLine(length = -50)
  |> xLine(length = -300)
  |> yLine(endAbsolute = profileStartY())
  |> xLine(endAbsolute = profileStartX(), tag = $seg01)
  |> close()
  |> revolve(axis = seg01)

// Insert a gear on the shaft
helicalGear(nTeeth = 14, helixAngle = 25deg, bore = 100)
  |> translate(x = 279, y = -200, z = -211)
  |> rotate(pitch = 10)


contra-rotor

KCL