// Brake Caliper
// Brake calipers are used to squeeze the brake pads against the rotor, causing larger and larger amounts of friction depending on how hard the brakes are pressed.

// Set units
@settings(defaultLengthUnit = in)

// Import parameters
import caliperTolerance, caliperPadLength, caliperThickness, caliperOuterEdgeRadius, caliperInnerEdgeRadius, rotorDiameter, rotorTotalThickness, yAxisOffset from "parameters.kcl"

// Sketch the brake caliper profile
brakeCaliperSketch = startSketchOn(XY)
  |> startProfileAt([
       rotorDiameter / 2 + caliperTolerance,
       0
     ], %)
  |> line(end = [
       0,
       rotorTotalThickness + caliperTolerance - caliperInnerEdgeRadius
     ])
  |> tangentialArc(angle = 90, radius = caliperInnerEdgeRadius)
  |> line(end = [
       -caliperPadLength + 2 * caliperInnerEdgeRadius,
       0
     ])
  |> tangentialArc(angle = -90, radius = caliperInnerEdgeRadius)
  |> line(end = [
       0,
       caliperThickness - (caliperInnerEdgeRadius * 2)
     ])
  |> tangentialArc(angle = -90, radius = caliperInnerEdgeRadius)
  |> line(end = [
       caliperPadLength + caliperThickness - caliperOuterEdgeRadius - caliperInnerEdgeRadius,
       0
     ])
  |> tangentialArc(angle = -90, radius = caliperOuterEdgeRadius)
  |> line(end = [
       0,
       -2 * caliperTolerance - (2 * caliperThickness) - rotorTotalThickness + 2 * caliperOuterEdgeRadius
     ])
  |> tangentialArc(angle = -90, radius = caliperOuterEdgeRadius)
  |> line(end = [
       -caliperPadLength - caliperThickness + caliperOuterEdgeRadius + caliperInnerEdgeRadius,
       0
     ])
  |> tangentialArc(angle = -90, radius = caliperInnerEdgeRadius)
  |> line(end = [
       0,
       caliperThickness - (2 * caliperInnerEdgeRadius)
     ])
  |> tangentialArc(angle = -90, radius = caliperInnerEdgeRadius)
  |> line(end = [
       caliperPadLength - (2 * caliperInnerEdgeRadius),
       0
     ])
  |> tangentialArc(angle = 90, radius = caliperInnerEdgeRadius)
  |> close()

// Revolve the brake caliper sketch
revolve(brakeCaliperSketch, axis = Y, angle = -70)
  |> appearance(color = "#c82d2d", metalness = 90, roughness = 90)


brake-caliper

// Wheel rotor
// A component of a disc brake system. It provides a surface for brake pads to press against, generating the friction needed to slow or stop the vehicle.

// Set units
@settings(defaultLengthUnit = in)

// Import parameters
import rotorDiameter, rotorInnerDiameter, rotorSinglePlateThickness, rotorInnerDiameterThickness, lugHolePatternDia, lugSpacing, rotorTotalThickness, spacerPatternDiameter, spacerDiameter, spacerLength, spacerCount, wheelDiameter, lugCount, yAxisOffset, drillAndSlotCount from "parameters.kcl"

rotorSketch = startSketchOn(XZ)
  |> circle(center = [0, 0], radius = rotorDiameter / 2)
rotor = extrude(rotorSketch, length = rotorSinglePlateThickness)
  |> appearance(color = "#dbcd70", roughness = 90, metalness = 90)

rotorBumpSketch = startSketchOn(rotor, face = END)
  |> circle(center = [0, 0], radius = rotorInnerDiameter / 2)
rotorBump = extrude(rotorBumpSketch, length = rotorInnerDiameterThickness)

lugHoles = startSketchOn(rotorBump, face = END)
  |> circle(center = [-lugSpacing / 2, 0], radius = 0.315)
  |> patternCircular2d(
       arcDegrees = 360,
       center = [0, 0],
       instances = lugCount,
       rotateDuplicates = true,
     )
  |> extrude(%, length = -(rotorInnerDiameterThickness + rotorSinglePlateThickness))
  |> appearance(color = "#dbcd70", roughness = 90, metalness = 90)

// (update when boolean is available)
centerSpacer = startSketchOn(rotor, face = START)
  |> circle(%, center = [0, 0], radius = .25)
  |> extrude(%, length = spacerLength)

secondaryRotorSketch = startSketchOn(centerSpacer, face = END)
  |> circle(center = [0, 0], radius = rotorDiameter / 2)
secondRotor = extrude(secondaryRotorSketch, length = rotorSinglePlateThickness)

lugHoles2 = startSketchOn(secondRotor, face = END)
  |> circle(center = [-lugSpacing / 2, 0], radius = 0.315)
  |> patternCircular2d(
       arcDegrees = 360,
       center = [0, 0],
       instances = lugCount,
       rotateDuplicates = true,
     )
  |> extrude(length = -rotorSinglePlateThickness)

spacerSketch = startSketchOn(rotor, face = START)
  |> circle(center = [spacerPatternDiameter / 2, 0], radius = spacerDiameter)
  |> patternCircular2d(
       arcDegrees = 360,
       center = [0, 0],
       instances = spacerCount,
       rotateDuplicates = true,
     )
spacers = extrude(spacerSketch, length = spacerLength)

rotorSlottedSketch = startSketchOn(rotor, face = START)
  |> startProfileAt([2.17, 2.56], %)
  |> xLine(length = 0.12)
  |> yLine(length = 2.56)
  |> xLine(length = -0.12)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()
  |> patternCircular2d(
       center = [0, 0],
       instances = drillAndSlotCount,
       arcDegrees = 360,
       rotateDuplicates = true,
     )
rotorSlotted = extrude(rotorSlottedSketch, length = -rotorSinglePlateThickness / 2)

secondRotorSlottedSketch = startSketchOn(secondRotor, face = END)
  |> startProfileAt([-2.17, 2.56], %)
  |> xLine(length = -0.12)
  |> yLine(length = 2.56)
  |> xLine(length = 0.12)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()
  |> patternCircular2d(
       center = [0, 0],
       instances = drillAndSlotCount,
       arcDegrees = 360,
       rotateDuplicates = true,
     )

extrude(secondRotorSlottedSketch, length = -rotorSinglePlateThickness / 2)
  |> appearance(color = "#dbcd70", roughness = 90, metalness = 90)


car-rotor

// Tire
// A tire is a critical component of a vehicle that provides the necessary traction and grip between the car and the road. It supports the vehicle's weight and absorbs shocks from road irregularities.

// Set units
@settings(defaultLengthUnit = in)

// Import parameters
import tireInnerDiameter, tireOuterDiameter, tireDepth, bendRadius, tireTreadWidth, tireTreadDepth, tireTreadOffset from "parameters.kcl"

// Create the sketch of the tire
tireSketch = startSketchOn(XY)
  |> startProfileAt([tireInnerDiameter / 2, tireDepth / 2], %)
  |> line(
       endAbsolute = [
         tireOuterDiameter / 2 - bendRadius,
         tireDepth / 2
       ],
       tag = $edge1,
     )
  |> tangentialArc(angle = -90, radius = bendRadius)
  |> line(endAbsolute = [
       tireOuterDiameter / 2,
       tireDepth / 2 - tireTreadOffset
     ])
  |> line(end = [-tireTreadDepth, 0])
  |> line(end = [0, -tireTreadWidth])
  |> line(end = [tireTreadDepth, 0])
  |> line(endAbsolute = [
       tireOuterDiameter / 2,
       -tireDepth / 2 + tireTreadOffset + tireTreadWidth
     ])
  |> line(end = [-tireTreadDepth, 0])
  |> line(end = [0, -tireTreadWidth])
  |> line(end = [tireTreadDepth, 0])
  |> line(endAbsolute = [
       tireOuterDiameter / 2,
       -tireDepth / 2 + bendRadius
     ])
  |> tangentialArc(angle = -90, radius = bendRadius)
  |> line(endAbsolute = [tireInnerDiameter / 2, -tireDepth / 2], tag = $edge2)
  |> close()

// Revolve the sketch to create the tire
revolve(tireSketch, axis = Y)
  |> appearance(color = "#0f0f0f", roughness = 80)


car-tire

// Car Wheel
// A sports car wheel with a circular lug pattern and spokes.

// Set units
@settings(defaultLengthUnit = in)

// Import parameters
import lugCount, lugSpacing, offset, backSpacing, wheelWidth, wheelDiameter, spokeCount, spokeGap, spokeAngle, spokeThickness from "parameters.kcl"

// Create the wheel center
lugBase = startSketchOn(XZ)
  |> circle(center = [0, 0], radius = (lugSpacing + 1.5) / 2)
  |> hole(circle(center = [0, 0], radius = (lugSpacing - 1.5) / 2), %)
  |> extrude(length = wheelWidth / 20)

// Extend the wheel center and bore holes to accomidate the lug heads
lugExtrusion = startSketchOn(lugBase, face = END)
  |> circle(center = [0, 0], radius = (lugSpacing + 1.5) / 2)
  |> hole(circle(center = [0, 0], radius = (lugSpacing - 1.5) / 2), %)
  |> extrude(length = wheelWidth / 10)

// Create the circular pattern for the lugs
lugClearance = startSketchOn(lugExtrusion, face = END)
  |> circle(center = [lugSpacing / 2, 0], radius = 1.2 / 2)
  |> patternCircular2d(
       arcDegrees = 360,
       center = [0, 0],
       instances = lugCount,
       rotateDuplicates = true,
     )
  |> extrude(length = -wheelWidth / 10)

// Create the circular pattern for the lug holes
lugHoles = startSketchOn(lugBase, face = END)
  |> circle(center = [lugSpacing / 2, 0], radius = fromMm(16) / 2)
  |> patternCircular2d(
       arcDegrees = 360,
       center = [0, 0],
       instances = lugCount,
       rotateDuplicates = true,
     )
  |> extrude(length = -wheelWidth / 20)
  |> appearance(color = "#ffffff", metalness = 0, roughness = 0)

// Add detail to the wheel center by revolving curved edge profiles
wheelCenterInner = startSketchOn(XY)
  |> startProfileAt([(lugSpacing - 1.5) / 2, 0], %)
  |> yLine(length = -wheelWidth / 10 - (wheelWidth / 20))
  |> bezierCurve({
       to = [-0.4, 0.3],
       control1 = [-0.3, 0],
       control2 = [0, 0.3]
     }, %)
  |> yLine(endAbsolute = 0)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()
  |> revolve(axis = Y)
  |> appearance(color = "#ffffff", metalness = 0, roughness = 0)

wheelCenterOuter = startSketchOn(XY)
  |> startProfileAt([(lugSpacing + 1.5) / 2, 0], %)
  |> yLine(length = -wheelWidth / 10 - (wheelWidth / 20))
  |> bezierCurve({
       to = [0.4, -0.1],
       control1 = [0.3, 0],
       control2 = [0.2, -0.3]
     }, %)
  |> yLine(endAbsolute = -wheelWidth / 20)
  |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
  |> close()
  |> revolve(axis = Y)
  |> appearance(color = "#ffffff", metalness = 0, roughness = 0)

// Write a function that defines the spoke geometry, patterns and extrudes it
fn spoke(spokeGap, spokeAngle, spokeThickness) {
  // Seperating the spoke base planes
  plane001 = {
    origin = [0.0, 0.0, spokeGap / 2],
    xAxis = [1.0, 0.0, spokeAngle],
    yAxis = [0.0, 1.0, 0.0],
    zAxis = [0.0, 0.0, 1.0]
  }

  // Spoke cross sections
  spokeProfile = startSketchOn(plane001)
    |> startProfileAt([(lugSpacing + 2) / 2, -0.7], %)
    |> bezierCurve({
         to = [
           (wheelDiameter - lugSpacing - 2.9) / 2,
           offset
         ],
         control1 = [
           (wheelDiameter - lugSpacing - 2.9) / 3.5,
           offset / 7
         ],
         control2 = [
           (wheelDiameter - lugSpacing - 2.9) / 4,
           offset / 1.5
         ]
       }, %)
    |> yLine(length = -wheelWidth / 15)
    |> bezierCurve({
         to = [
           -(wheelDiameter - lugSpacing - 2.9) / 2,
           -offset
         ],
         control1 = [
           -(wheelDiameter - lugSpacing - 2.9) / 5,
           -offset / 7
         ],
         control2 = [
           -(wheelDiameter - lugSpacing - 2.9) / 5,
           -offset / 1.5
         ]
       }, %)
    |> line(endAbsolute = [profileStartX(%), profileStartY(%)])
    |> close()

  // Circular pattern spokes
  spokePattern = extrude(spokeProfile, length = spokeThickness)
    |> patternCircular3d(
         axis = [0, 1, 0],
         center = [0, -2000, 0],
         instances = spokeCount,
         arcDegrees = 360,
         rotateDuplicates = true,
       )
    |> appearance(color = "#ffffff", metalness = 0, roughness = 0)
  return spokePattern
}

spoke(spokeGap, spokeAngle, spokeThickness)
spoke(-spokeGap, -spokeAngle, -spokeThickness)

// Define and revolve wheel exterior
startSketchOn(XY)
  |> startProfileAt([
       wheelDiameter / 2,
       -wheelWidth + backSpacing + offset
     ], %)
  |> yLine(length = wheelWidth * 0.25)
  |> line(end = [-wheelWidth * 0.02, wheelWidth * 0.02])
  |> yLine(length = wheelWidth * 0.25)
  |> line(end = [wheelWidth * 0.02, wheelWidth * 0.02])
  |> yLine(endAbsolute = backSpacing + offset)
  |> line(end = [wheelWidth * 0.05, wheelWidth * .01])
  |> yLine(length = wheelWidth * 0.05)
  |> xLine(length = -wheelWidth * 0.03)
  |> yLine(length = -wheelWidth * 0.02)
  |> line(end = [-wheelWidth * 0.05, -wheelWidth * 0.01])
  |> yLine(length = -backSpacing * 0.7)
  |> line(end = [
       -wheelDiameter * 0.01,
       -wheelWidth * 0.02
     ])
  |> yLine(endAbsolute = offset - 0.2)
  |> line(end = [
       -wheelDiameter * 0.03,
       -wheelWidth * 0.02
     ])
  |> yLine(length = -wheelWidth * 0.02)
  |> line(end = [
       wheelDiameter * 0.03,
       -wheelWidth * 0.1
     ])
  |> yLine(length = -wheelWidth * 0.05)
  |> line(end = [wheelWidth * 0.02, -wheelWidth * 0.02])
  |> yLine(endAbsolute = -wheelWidth + backSpacing + offset - 0.28)
  |> line(end = [wheelWidth * 0.05, -wheelWidth * 0.01])
  |> yLine(length = -wheelWidth * 0.02)
  |> xLine(length = wheelWidth * 0.03)
  |> yLine(length = wheelWidth * 0.05)
  |> close()
  |> revolve(axis = Y)
  |> appearance(color = "#ffffff", metalness = 0, roughness = 0)


car-wheel

// Lug Nut
// lug Nuts are essential components used to create secure connections, whether for electrical purposes, like terminating wires or grounding, or for mechanical purposes, such as providing mounting points or reinforcing structural joints.

// Set units
@settings(defaultLengthUnit = in)

// Import parameters
import lugDiameter, lugHeadLength, lugThreadDiameter, lugLength, lugThreadDepth, lugSpacing from "parameters.kcl"

customPlane = {
  origin = {
    x = lugSpacing / 2,
    y = fromMm(-30),
    z = 0
  },
  xAxis = { x = 1, y = 0, z = 0 },
  yAxis = { x = 0, y = -1, z = 0 },
  zAxis = { x = 0, y = 0, z = 1 }
}

fn lug(plane, length, diameter) {
  lugSketch = startSketchOn(customPlane)
    |> startProfileAt([0 + diameter / 2, 0], %)
    |> angledLine(angle = 70, lengthY = lugHeadLength)
    |> xLine(endAbsolute = lugDiameter / 2)
    |> yLine(endAbsolute = lugLength)
    |> tangentialArc(angle = 90, radius = fromMm(3))
    |> xLine(endAbsolute = 0 + .001, tag = $c1)
    |> yLine(endAbsolute = lugThreadDepth)
    |> xLine(endAbsolute = lugThreadDiameter)
    |> yLine(endAbsolute = 0)
    |> close()
    |> revolve(axis = Y)
    |> appearance(color = "#dbcd70", roughness = 90, metalness = 90)
  return lugSketch
}

lug(customPlane, lugLength, lugDiameter)


lug-nut

// Car wheel assembly parameters

// Set units
@settings(defaultLengthUnit = in)

// Car wheel
export lugCount = 5
export lugSpacing = fromMm(114.3)
export offset = fromMm(-35)
export backSpacing = 6.38
export wheelWidth = 9.5
export wheelDiameter = 19
export spokeCount = 6
export spokeGap = 0.2
export spokeAngle = 0.02
export spokeThickness = 0.95

// Lug Nut
export lugDiameter = fromMm(24)
export lugHeadLength = lugDiameter * .5
export lugThreadDiameter = lugDiameter / 2 * .85
export lugLength = fromMm(30)
export lugThreadDepth = lugLength - fromMm(12.7)

// Car rotor
export rotorDiameter = 12
export rotorInnerDiameter = 6
export rotorSinglePlateThickness = 0.25
export rotorInnerDiameterThickness = 0.5
export lugHolePatternDia = 3
export rotorTotalThickness = 1
export spacerPatternDiameter = 11
export spacerDiameter = 0.25
export spacerLength = rotorTotalThickness - (2 * rotorSinglePlateThickness)
export spacerCount = 16
export yAxisOffset = 0.5
export drillAndSlotCount = 5

// Car tire
export tireInnerDiameter = 19
export tireOuterDiameter = 24
export tireDepth = 11.02
export bendRadius = 1.6
export tireTreadWidth = 0.39
export tireTreadDepth = 0.39
export tireTreadOffset = 3.15

// Brake caliper
export caliperTolerance = 0.050
export caliperPadLength = 1.6
export caliperThickness = 0.39
export caliperOuterEdgeRadius = 0.39
export caliperInnerEdgeRadius = 0.12


parameters

Authentication

Errors

Generate a CAD model from text.

List all ML prompts.

Get a ML prompt.

Generate code completions for KCL.

Iterate on a CAD model with a prompt.

Iterate on a multi-file CAD model with a prompt.

List text-to-CAD models you've generated.

Get a text-to-CAD response.

Give feedback to a specific ML response.

Open a websocket which accepts modeling commands.

Modeling

Get API call metrics.

List API calls.

Get details of an API call.

List async operations.

Get an async operation.

List API calls for your org.

Get an API call for an org.

List API calls for your user.

Get an API call for a user.

List API calls for a user.

API Calls

List API tokens for your user.

Create a new API token for your user.

Get an API token for your user.

Delete an API token for your user.

API Tokens

Listen for callbacks to GitHub app authentication.

Get the consent URL for GitHub app authentication.

Listen for GitHub webhooks.

Apps

Execute a Zoo program in a specific language.

Create a terminal.

Executor

Get CAD file center of mass.

Convert CAD file with defaults.

Get CAD file density.

Get CAD file mass.

Get CAD file surface area.

Get CAD file volume.

File

Get OpenAPI schema.

Get the metadata about our currently running server.

Get ip address information.

Authorize an inbound auth request from our Community page.

Uploads files to public blob storage for debugging purposes.

Creates an internal telemetry event.

Get an API token for a user by their discord ID.

Return pong.

Get the pricing for our subscriptions.

Start an OAuth 2.0 Device Authorization Grant.

Confirm an OAuth 2.0 Device Authorization Grant.

Request a device access token.

Verify an OAuth 2.0 Device Authorization Grant.

Listen for callbacks for the OAuth 2.0 provider.

Get the consent URL and other information for the OAuth 2.0 provider.

Revoke an OAuth2 token.

Oauth2

Get an org.

Update an org.

Create an org.

Delete an org.

List members of your org.

Add a member to your org.

Get a member of your org.

Update a member of your org.

Remove a member from your org.

Get the privacy settings for an org.

Update the privacy settings for an org.

Get the SAML identity provider.

Update the SAML identity provider.

Create a SAML identity provider.

Delete an SAML identity provider.

Get the shortlinks for an org.

List orgs.

Set the enterprise price for an organization.

Get a user's org.

Orgs

Get payment info about your org.

Update payment info for your org.

Create payment info for your org.

Delete payment info for your org.

Get balance for your org.

Create a payment intent for your org.

List invoices for your org.

List payment methods for your org.

Delete a payment method for your org.

Get the subscription for an org.

Update the subscription for an org.

Create the subscription for an org.

Validate an orgs's information is correct and valID for automatic tax.

Get balance for an org.

Update balance for an org.

Get payment info about your user.

Update payment info for your user.

Create payment info for your user.

Delete payment info for your user.

Get balance for your user.

Create a payment intent for your user.

List invoices for your user.

List payment methods for your user.

Delete a payment method for your user.

Get the subscription for a user.

Update the user's subscription.

Create the subscription for a user.

Validate a user's information is correct and valID for automatic tax.

Get balance for an user.

Update balance for an user.

Payments

List service accounts for your org.

Create a new service account for your org.

Get an service account for your org.

Delete an service account for your org.

Service Accounts

Get the shortlinks for a user.

Create a shortlink for a user.

Redirect the user to the URL for the shortlink.

Update a shortlink for a user.

Delete a shortlink for a user.

Shortlinks

Create a new store coupon.

Store

Convert angle units.

Convert area units.

Convert current units.

Convert energy units.

Convert force units.

Convert frequency units.

Convert length units.

Convert mass units.

Convert power units.

Convert pressure units.

Convert temperature units.

Convert torque units.

Convert volume units.

Unit

Get your user.

Update your user.

Delete your user.

Get extended information about your user.

Get the OAuth2 providers for your user.

Get your user's onboarding status.

Get the privacy settings for a user.

Update the user's privacy settings.

Get a session for your user.

List users.

List users with extended information.

Get extended information about a user.

Get a user.

Users

zoo alias delete

delete

zoo alias list

list

zoo alias set

zoo alias

alias

zoo api-call status

status

zoo api-call

api-call

zoo api

zoo app

zoo auth login

login

zoo auth logout

logout

zoo auth status

zoo auth

auth

zoo completion

completion

zoo config get

zoo config list

zoo config set

zoo config

config

zoo drake

drake

zoo file center-of-mass

center-of-mass

zoo file convert

convert

zoo file density

density

zoo file mass

mass

zoo file

file

car-wheel-assembly

car-wheel-assembly

KCL

Parts